home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 2: Applications / Linux Cubed Series 2 - Applications.iso / editors / emacs / xemacs / xemacs-1.006 / xemacs-1 / lib / xemacs-19.13 / lisp / utils / derived.el < prev    next >
Encoding:
Text File  |  1995-05-13  |  12.6 KB  |  335 lines
  1. ;;; derived.el --- allow inheritance of major modes.
  2.  
  3. ;;; (formerly mode-clone.el)
  4.  
  5. ;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
  6.  
  7. ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
  8. ;; Keywords: extensions
  9. ;; Maintainer: FSF
  10.  
  11. ;; This file is part of XEmacs.
  12.  
  13. ;; XEmacs is free software; you can redistribute it and/or modify it
  14. ;; under the terms of the GNU General Public License as published by
  15. ;; the Free Software Foundation; either version 2, or (at your option)
  16. ;; any later version.
  17.  
  18. ;; XEmacs is distributed in the hope that it will be useful, but
  19. ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21. ;; General Public License for more details.
  22.  
  23. ;; You should have received a copy of the GNU General Public License
  24. ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  25. ;; Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  26.  
  27. ;;; Commentary:
  28.  
  29. ;; GNU Emacs is already, in a sense, object oriented -- each object
  30. ;; (buffer) belongs to a class (major mode), and that class defines
  31. ;; the relationship between messages (input events) and methods
  32. ;; (commands) by means of a keymap.
  33. ;;
  34. ;; The only thing missing is a good scheme of inheritance.  It is
  35. ;; possible to simulate a single level of inheritance with generous
  36. ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37. ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38. ;; -- but generally, each major mode ends up reinventing the wheel.
  39. ;; Ideally, someone should redesign all of Emacs's major modes to
  40. ;; follow a more conventional object-oriented system: when defining a
  41. ;; new major mode, the user should need only to name the existing mode
  42. ;; it is most similar to, then list the (few) differences.
  43. ;;
  44. ;; In the mean time, this package offers most of the advantages of
  45. ;; full inheritance with the existing major modes.  The macro
  46. ;; `define-derived-mode' allows the user to make a variant of an existing
  47. ;; major mode, with its own keymap.  The new mode will inherit the key
  48. ;; bindings of its parent, and will, in fact, run its parent first
  49. ;; every time it is called.  For example, the commands
  50. ;;
  51. ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52. ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53. ;;    (setq case-fold-search nil))
  54. ;;
  55. ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56. ;;
  57. ;; will create a function `hypertext-mode' with its own (sparse)
  58. ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59. ;; perform the following actions:
  60. ;;
  61. ;; - run the command (text-mode) to get its default setup
  62. ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63. ;;   inherit from 'text-mode-map'.
  64. ;; - replace the current syntax table with
  65. ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66. ;;   from the current text-mode-syntax-table.
  67. ;; - replace the current abbrev table with
  68. ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69. ;;   from the current text-mode-abbrev table
  70. ;; - change the mode line to read "Hypertext"
  71. ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72. ;; - run the body of commands provided in the macro -- in this case,
  73. ;;   set the local variable `case-fold-search' to nil.
  74. ;; - **run the command (hypertext-mode-setup), which is empty by
  75. ;;   default, but may be redefined by the user to contain special
  76. ;;   commands (ie. setting local variables like 'outline-regexp')
  77. ;;   **NOTE: do not use this option -- it will soon be obsolete.
  78. ;; - run anything assigned to 'hypertext-mode-hooks' (obsolete, but
  79. ;;   supported for the sake of compatibility).
  80. ;;
  81. ;; The advantages of this system are threefold.  First, text mode is
  82. ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  83. ;; possibly using hooks, you would have added it to all text buffers
  84. ;; -- here, it appears only in hypertext buffers, where it makes
  85. ;; sense.  Second, it is possible to build even further, and make
  86. ;; a derived mode from a derived mode.  The commands
  87. ;;
  88. ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  89. ;;   [various key definitions]
  90. ;; 
  91. ;; will add a new major mode for HTML with very little fuss.
  92. ;;
  93. ;; Note also the function `derived-mode-class,' which returns the non-derived
  94. ;; major mode which a derived mode is based on (ie. NOT necessarily the
  95. ;; immediate parent).
  96. ;;
  97. ;; (derived-mode-class 'text-mode) ==> text-mode
  98. ;; (derived-mode-class 'hypertext-mode) ==> text-mode
  99. ;; (derived-mode-class 'html-mode) ==> text-mode
  100.  
  101. ;;; Code:
  102.  
  103. ;; PUBLIC: define a new major mode which inherits from an existing one.
  104.  
  105. ;;;###autoload
  106. (defmacro define-derived-mode (child parent name &optional docstring &rest body)
  107.   "Create a new mode as a variant of an existing mode.
  108.  
  109. The arguments to this command are as follow:
  110.  
  111. PARENT:    the name of the command for the parent mode (ie. text-mode).
  112. CHILD:     the name of the command for the derived mode.
  113. NAME:      a string which will appear in the status line (ie. \"Hypertext\")
  114. DOCSTRING: an optional documentation string--if you do not supply one,
  115.            the function will attempt to invent something useful.
  116. BODY:      forms to execute just before running the
  117.            hooks for the new mode.
  118.  
  119. Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
  120.  
  121.   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
  122.  
  123. You could then make new key bindings for `LaTeX-thesis-mode-map'
  124. without changing regular LaTeX mode.  In this example, BODY is empty,
  125. and DOCSTRING is generated by default.
  126.  
  127. On a more complicated level, the following command uses sgml-mode as
  128. the parent, and then sets the variable `case-fold-search' to nil:
  129.  
  130.   (define-derived-mode article-mode sgml-mode \"Article\"
  131.     \"Major mode for editing technical articles.\"
  132.     (setq case-fold-search nil))
  133.  
  134. Note that if the documentation string had been left out, it would have
  135. been generated automatically, with a reference to the keymap."
  136.  
  137.                     ; Some trickiness, since what
  138.                     ; appears to be the docstring
  139.                     ; may really be the first
  140.                     ; element of the body.
  141.   (if (and docstring (not (stringp docstring)))
  142.       (progn (setq body (cons docstring body))
  143.          (setq docstring nil)))
  144.   (setq docstring (or docstring (derived-mode-make-docstring parent child)))
  145.  
  146.   (` (progn 
  147.        (derived-mode-init-mode-variables (quote (, child)))
  148.        (defun (, child) ()
  149.      (, docstring)
  150.      (interactive)
  151.                     ; Run the parent.
  152.      ((, parent))
  153.                     ; Identify special modes.
  154.      (if (get (quote (, parent)) 'special)
  155.          (put (quote (, child)) 'special t))
  156.                     ; Identify the child mode.
  157.      (setq major-mode (quote (, child)))
  158.      (setq mode-name (, name))
  159.                     ; Set up maps and tables.
  160.      (derived-mode-set-keymap (quote (, child)))
  161.      (derived-mode-set-syntax-table (quote (, child)))
  162.      (derived-mode-set-abbrev-table (quote (, child)))
  163.                     ; Splice in the body (if any).
  164.      (,@ body)
  165. ;;;                    ; Run the setup function, if
  166. ;;;                    ; any -- this will soon be
  167. ;;;                    ; obsolete.
  168. ;;;     (derived-mode-run-setup-function (quote (, child)))
  169.                     ; Run the hooks, if any.
  170.      (derived-mode-run-hooks (quote (, child)))))))
  171.  
  172.  
  173. ;; PUBLIC: find the ultimate class of a derived mode.
  174.  
  175. (defun derived-mode-class (mode)
  176.   "Find the class of a major mode.
  177. A mode's class is the first ancestor which is NOT a derived mode.
  178. Use the `derived-mode-parent' property of the symbol to trace backwards."
  179.   (while (get mode 'derived-mode-parent)
  180.     (setq mode (get mode 'derived-mode-parent)))
  181.   mode)
  182.  
  183.  
  184. ;; Inline functions to construct various names from a mode name.
  185.  
  186. (defsubst derived-mode-setup-function-name (mode)
  187.   "Construct a setup-function name based on a mode name."
  188.   (intern (concat (symbol-name mode) "-setup")))
  189.  
  190. (defsubst derived-mode-hooks-name (mode)
  191.   "Construct a hooks name based on a mode name."
  192.   (intern (concat (symbol-name mode) "-hooks")))
  193.  
  194. (defsubst derived-mode-map-name (mode)
  195.   "Construct a map name based on a mode name."
  196.   (intern (concat (symbol-name mode) "-map")))
  197.  
  198. (defsubst derived-mode-syntax-table-name (mode)
  199.   "Construct a syntax-table name based on a mode name."
  200.   (intern (concat (symbol-name mode) "-syntax-table")))
  201.  
  202. (defsubst derived-mode-abbrev-table-name (mode)
  203.   "Construct an abbrev-table name based on a mode name."
  204.   (intern (concat (symbol-name mode) "-abbrev-table")))
  205.  
  206.  
  207. ;; Utility functions for defining a derived mode.
  208.  
  209. ;;;###autoload
  210. (defun derived-mode-init-mode-variables (mode)
  211.   "Initialise variables for a new mode. 
  212. Right now, if they don't already exist, set up a blank keymap, an
  213. empty syntax table, and an empty abbrev table -- these will be merged
  214. the first time the mode is used."
  215.  
  216.   (if (boundp (derived-mode-map-name mode))
  217.       t
  218.     (eval (` (defvar (, (derived-mode-map-name mode)) 
  219.            (make-sparse-keymap)
  220.            (, (format "Keymap for %s." mode)))))
  221.     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
  222.  
  223.   (if (boundp (derived-mode-syntax-table-name mode))
  224.       t
  225.     (eval (` (defvar (, (derived-mode-syntax-table-name mode))
  226.            (make-vector 256 nil)
  227.            (, (format "Syntax table for %s." mode)))))
  228.     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
  229.  
  230.   (if (boundp (derived-mode-abbrev-table-name mode))
  231.       t
  232.     (eval (` (defvar (, (derived-mode-abbrev-table-name mode))
  233.            (progn (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
  234.               (make-abbrev-table))
  235.            (, (format "Abbrev table for %s." mode)))))))
  236.  
  237. (defun derived-mode-make-docstring (parent child)
  238.   "Construct a docstring for a new mode if none is provided."
  239.  
  240.   (format "This major mode is a variant of `%s', created by `define-derived-mode'.
  241. It inherits all of the parent's attributes, but has its own keymap,
  242. abbrev table and syntax table:
  243.  
  244.   `%s-map' and `%s-syntax-table'
  245.  
  246. which more-or-less shadow
  247.  
  248.   `%s-map' and `%s-syntax-table'
  249.  
  250. \\{%s-map}" parent child child parent parent child))
  251.  
  252.  
  253. ;; Utility functions for running a derived mode.
  254.  
  255. (defun derived-mode-set-keymap (mode)
  256.   "Set the keymap of the new mode, maybe merging with the parent."
  257.   (let* ((map-name (derived-mode-map-name mode))
  258.      (new-map (eval map-name))
  259.      (old-map (current-local-map)))
  260.     (if (get map-name 'derived-mode-unmerged)
  261.     (derived-mode-merge-keymaps old-map new-map))
  262.     (put map-name 'derived-mode-unmerged nil)
  263.     (use-local-map new-map)))
  264.  
  265. (defun derived-mode-set-syntax-table (mode) 
  266.   "Set the syntax table of the new mode, maybe merging with the parent."
  267.   (let* ((table-name (derived-mode-syntax-table-name mode))
  268.      (old-table (syntax-table))
  269.      (new-table (eval table-name)))
  270.     (if (get table-name 'derived-mode-unmerged)
  271.     (derived-mode-merge-syntax-tables old-table new-table))
  272.     (put table-name 'derived-mode-unmerged nil)
  273.     (set-syntax-table new-table)))
  274.  
  275. (defun derived-mode-set-abbrev-table (mode)
  276.   "Set the abbrev table if it exists.  
  277. Always merge its parent into it, since the merge is non-destructive."
  278.   (let* ((table-name (derived-mode-abbrev-table-name mode))
  279.      (old-table local-abbrev-table)
  280.      (new-table (eval table-name)))
  281.     (derived-mode-merge-abbrev-tables old-table new-table)
  282.     (setq local-abbrev-table new-table)))
  283.  
  284. ;;;(defun derived-mode-run-setup-function (mode)
  285. ;;;  "Run the setup function if it exists."
  286.  
  287. ;;;  (let ((fname (derived-mode-setup-function-name mode)))
  288. ;;;    (if (fboundp fname)
  289. ;;;    (funcall fname))))
  290.  
  291. (defun derived-mode-run-hooks (mode)
  292.   "Run the hooks if they exist."
  293.  
  294.   (let ((hooks-name (derived-mode-hooks-name mode)))
  295.     (if (boundp hooks-name)
  296.     (run-hooks hooks-name))))
  297.  
  298. ;; Functions to merge maps and tables.
  299.  
  300. (defun derived-mode-merge-keymaps (old new)
  301.   "Merge an old keymap into a new one.
  302. The old keymap is set to be the cdr of the new one, so that there will
  303. be automatic inheritance."
  304.   (if (fboundp 'set-keymap-parent)
  305.       (set-keymap-parent new old)
  306.  (setcdr (nthcdr (1- (length new)) new) old)))
  307.  
  308. (defun derived-mode-merge-syntax-tables (old new)
  309.   "Merge an old syntax table into a new one.
  310. Where the new table already has an entry, nothing is copied from the old one."
  311.   (let ((idx 0)
  312.     (end (min (length new) (length old))))
  313.     (while (< idx end)
  314.       (if (not (aref new idx))
  315.       (aset new idx (aref old idx)))
  316.       (setq idx (1+ idx)))))
  317.  
  318. ;; Merge an old abbrev table into a new one.
  319. ;; This function requires internal knowledge of how abbrev tables work,
  320. ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
  321. ;; as the value of the symbol, and the hook as the function definition.
  322. (defun derived-mode-merge-abbrev-tables (old new)
  323.   (if old
  324.       (mapatoms 
  325.        (function 
  326.     (lambda (symbol)
  327.       (or (intern-soft (symbol-name symbol) new)
  328.           (define-abbrev new (symbol-name symbol)
  329.         (symbol-value symbol) (symbol-function symbol)))))
  330.        old)))
  331.     
  332. (provide 'derived)
  333.  
  334. ;;; derived.el ends here
  335.